home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / G-Games / (c)gb.d64 / e puzzle.d (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  6KB  |  171 lines
  1. 1 REM - THE 'E' PUZZLE FOR COMMODORE 64
  2. 2 REM- DANIEL MILLER
  3. 3 REM- 2815 34 STREET
  4. 4 REM- ASTORIA, QUEENS
  5. 5 REM- NEW YORK, NEW YORK   11103
  6. 6 REM- APRIL 4, 1983
  7. 7 REM********************************
  8. 20 DIM B(12),C(12),A$(9),ER$(3)
  9. 30 GOSUB10000:GOTO1005
  10. 35 REM- SOUND ROUTINE
  11. 40 POKEVO,15:POKEWV,17:POKEAT,15:POKEHI,68:POKELO,149
  12. 50 FOR TM=1 TO 100:NEXT TM:POKEWV,0
  13. 55 POKEVO,15:POKEWV,17:POKEAT,15:POKEHI,34:POKELO,75
  14. 60 FOR TM=1 TO 100:NEXT TM:POKEWV,0:RETURN
  15. 300 REM- PUZZLE SCREEN
  16. 302 PRINTCHR$(19);TAB(22-(LEN(HDG$)/2));HDG$
  17. 303 X=49:FOR Y=1159 TO 1168 STEP3:POKEY,X:POKE Y+54272,14:X=X+1:NEXT Y
  18. 305 PRINT LEFT$(DO$,5);
  19. 310 PRINTTAB(14)A$(B(1));UP$;A$(B(2));UP$;A$(B(3));UP$;A$(B(4))
  20. 317 IF VAL(F2$)<>1 THEN320
  21. 318 GOSUB40
  22. 320 PRINTTAB(17)A$(B(5))
  23. 327 IF VAL(F2$)<>2 THEN330
  24. 328 GOSUB40
  25. 330 PRINTTAB(17)A$(B(6));UP$;A$(B(7))
  26. 337 IF VAL(F2$)<>3 THEN340
  27. 338 GOSUB40
  28. 340 PRINTTAB(17)A$(B(8))
  29. 347 IF VAL(F2$)<>4 THEN350
  30. 348 GOSUB40
  31. 350 PRINTTAB(14)A$(B(9));UP$;A$(B(10));UP$;A$(B(11));UP$;A$(B(12))
  32. 352 IF VAL(F2$)<>5 THEN355
  33. 353 GOSUB40
  34. 355 X=49:FOR Y=1235 TO 1715 STEP120:POKEY,X:POKE Y+54272,14:X=X+1:NEXT Y
  35. 360 PRINTLEFT$(DO$,21);TAB(18);MV$;
  36. 365 PRINTLEFT$(DO$,23);TAB(12);F3$;TAB(27);T3$;
  37. 366 IF ZZ=1 THEN FOR TM=1 TO 2000:NEXT TM:RETURN
  38. 370 REM- PUZZLE SOLVED ?
  39. 375 IF D$=D1$ THEN600
  40. 400 PRINTLEFT$(DO$,23);TAB(20);"    ";TAB(31);"    ";
  41. 405 PRINTLEFT$(DO$,23);TAB(20);"   ";LEFT$(DO$,23);TAB(20);CR$;
  42. 410 GET F$:IF F$="" THEN410
  43. 412 GET G$:IF G$="" THEN412
  44. 415 FR$=F$+G$:PRINT FR$;:F$="":G$=""
  45. 417 IF FR$="99" THEN8310
  46. 419 IF LEFT$(FR$,1)<"1" OR LEFT$(FR$,1)>"5" THEN FR$="":GOTO405
  47. 421 IF RIGHT$(FR$,1)<"1" OR RIGHT$(FR$,1)>"4" THEN FR$="":GOTO405
  48. 423 H=VAL(FR$):GOSUB8000:FR=H:C(FR)=VAL(MID$(D$,FR,1))
  49. 430 PRINTLEFT$(DO$,23);TAB(31);"    ";LEFT$(DO$,23);TAB(32);CR$;
  50. 432 GET F$:IF F$="" THEN432
  51. 434 GET G$:IF G$="" THEN434
  52. 436 TU$=F$+G$:PRINTTU$;:F$="":G$=""
  53. 438 IF LEFT$(TU$,1)<"1" OR LEFT$(TU$,1)>"5" THEN TU$="":GOTO430
  54. 440 IF RIGHT$(TU$,1)<"1" OR RIGHT$(TU$,1)>"4" THEN TU$="":GOTO430
  55. 442 H=VAL(TU$):GOSUB8000:TU=H:C(TU)=VAL(MID$(D$,TU,1))
  56. 443 F2$=LEFT$(FR$,1)
  57. 444 FR$=MID$(D$,FR,1):TU$=MID$(D$,TU,1)
  58. 445 IF FR$="6" OR FR$="3" OR FR$="7" THEN ER=1:GOTO900
  59. 446 IF TU$="1" OR TU$="8" OR TU$="2" OR TU$="9" THEN ER=2:GOTO900
  60. 447 IF TU$="4" OR TU$="5" THEN ER=2:GOTO900
  61. 451 IF FR$="1" AND TU$="6" THEN C(TU)=6:C(FR)=1:GOTO468
  62. 452 IF FR$="2" AND TU$="6" THEN C(TU)=7:C(FR)=8:GOTO468
  63. 453 IF FR$="2" AND TU$="7" THEN C(TU)=7:C(FR)=2:GOTO468
  64. 454 IF FR$="4" AND TU$="6" THEN C(TU)=3:C(FR)=8:GOTO468
  65. 455 IF FR$="5" AND TU$="7" THEN C(TU)=3:C(FR)=9:GOTO468
  66. 456 IF FR$="8" AND TU$="3" THEN C(TU)=6:C(FR)=4:GOTO468
  67. 457 IF FR$="9" AND TU$="3" THEN C(TU)=7:C(FR)=5:GOTO468
  68. 458 IF FR$="5" AND TU$="6" THEN C(TU)=3:C(FR)=1:GOTO468
  69. 464 IF FR$="1" THEN C(TU)=6:C(FR)=5:GOTO468
  70. 465 IF FR$="4" THEN C(TU)=3:C(FR)=4:GOTO468
  71. 466 IF FR$="2" THEN C(TU)=7:C(FR)=4:GOTO468
  72. 468 C=C(TU):C(TU)=C(FR):C(FR)=C
  73. 470 D$="":FOR X=1 TO 12:D$=D$+RIGHT$(STR$(C(X)),1):NEXT X
  74. 480 PRINTLEFT$(DO$,23);TAB(20);"    ";TAB(31);"    ";
  75. 490 FOR X=1 TO 12:B(X)=VAL(MID$(D$,X,1)):NEXT X
  76. 500 MV=MV+1:MO$=RV$+WH$+STR$(MV)+RO$:PRINTLEFT$(DO$,21);TAB(25);MO$;:GOTO302
  77. 600 FOR X=1 TO 5
  78. 610 PRINTLEFT$(DO$,25);TAB(8);WIN$;:FOR TM=1 TO 500:NEXT TM
  79. 620 PRINTLEFT$(DO$,25);TAB(8);ER$(0);:FOR TM=1 TO 500:NEXT TM:NEXT X
  80. 630 GOTO8310
  81. 899 REM- FLASH ERROR MESSAGES
  82. 900 F2$="":FOR X=1 TO 5
  83. 910 PRINT LEFT$(DO$,25);TAB(22-LEN(ER$(ER))/2);ER$(ER);:FOR TM=1 TO 500:NEXT TM
  84. 920 PRINT LEFT$(DO$,25);TAB(9);ER$(0);:FOR TM=1 TO 500:NEXT TM:NEXT X:GOTO302
  85. 1000 REM- INSTRUCTIONS
  86. 1005 POKE 53281,1
  87. 1010 PRINT CL$;LEFT$(DO$,3);TAB(14);H2$:PRINT:PRINT
  88. 1020 PRINT"     [217]OUR MISSION (SHOULD YOU DECIDE TO":PRINT
  89. 1030 PRINT"   ACCEPT IT): [211]OLVE THIS PUZZLE IN THE":PRINT
  90. 1035 PRINT"   LEAST NUMBER OF MOVES.":PRINT
  91. 1040 PRINT"     [208]EGS ARE ARRANGED ON THE PLAYING":PRINT
  92. 1050 PRINT"   SCREEN AS FOLLOWS:"
  93. 1060 ZZ=1:FOR TM=1 TO 2000:NEXT TM:PRINT CL$;UC$;:GOSUB1500:POKE53281,1
  94. 1070 PRINT CL$;LEFT$(DO$,3);TAB(14);H2$:PRINT:PRINT:ZZ=0
  95. 1080 PRINT"     [210]EVERSE THE PEGS TO THE OPPOSITE":PRINT
  96. 1090 PRINT"   POSITIONS IN THE '[197]'.":PRINT:PRINT
  97. 1100 PRINT"     [205]OVE EACH PEG TO AN EMPTY SPACE OR":PRINT
  98. 1110 PRINT"   OVER ANOTHER PEG TO AN EMPTY SPACE.":PRINT:PRINT
  99. 1120 PRINT"     [199]OOD [204]UCK AND [200]APPY [208]UZZLING !"
  100. 1130 FOR TM=1 TO 3000:NEXT TM
  101. 1500 GOSUB11000:FOR X=1 TO LEN(D$):B(X)=VAL(MID$(D$,X,1)):C(X)=B(X):NEXT:F2$=""
  102. 1510 MV=0:POKE53281,11:PRINT CL$;UC$;:GOTO302
  103. 8000 REM- CONVERT 'FROM-TO' TO POSITION IN STRING
  104. 8010 IF H=11 THEN H=1:RETURN
  105. 8020 IF H=12 THEN H=2:RETURN
  106. 8030 IF H=13 THEN H=3:RETURN
  107. 8040 IF H=14 THEN H=4:RETURN
  108. 8050 IF H=22 THEN H=5:RETURN
  109. 8060 IF H=32 THEN H=6:RETURN
  110. 8070 IF H=33 THEN H=7:RETURN
  111. 8080 IF H=42 THEN H=8:RETURN
  112. 8090 IF H=51 THEN H=9:RETURN
  113. 8100 IF H=52 THEN H=10:RETURN
  114. 8110 IF H=53 THEN H=11:RETURN
  115. 8120 IF H=54 THEN H=12:RETURN
  116. 8200 REM- MOVE INVALID
  117. 8210 FOR X=1 TO 5
  118. 8220 PRINTLEFT$(DO$,25);TAB(9);ER$(3);:FOR TM=1 TO 500:NEXT TM
  119. 8230 PRINTLEFT$(DO$,25);TAB(9);ER$(0);:FOR TM=1 TO 500:NEXT TM
  120. 8240 NEXT X:F2$="":GOTO302
  121. 8300 REM- END PUZZLE MESSAGE
  122. 8310 PRINTLEFT$(DO$,25);TAB(7);EN$;:FOR TM=1 TO 1500:NEXT TM:PRINT CL$:END
  123. 10000 REM- BUILD CHARACTER GRAPHICS
  124. 10100 WH$=CHR$(5):BLK$=CHR$(144):RED$=CHR$(28):GRN$=CHR$(30):YEL$=CHR$(158)
  125. 10105 CYN$=CHR$(159):B2LU$=CHR$(31)
  126. 10110 DW$=CHR$(17):UP$=CHR$(145)+CHR$(145)
  127. 10120 FOR X=1 TO 24:DO$=DO$+DW$:NEXT X:DO$=CHR$(19)+DO$
  128. 10130 LF$=CHR$(157)+CHR$(157)+CHR$(157)
  129. 10140 LC$=CHR$(14):UC$=CHR$(142)
  130. 10145 RV$=CHR$(18):RO$=CHR$(146)
  131. 10150 PEG$=CHR$(113):CL$=CHR$(147)
  132. 10160 A$(1)=RV$+RED$+"   "+RO$+DW$+LF$+RV$+RED$+" "+RO$+WH$+PE$
  133. 10165 A$(1)=A$(1)+RV$+RED$+" "+RO$+DW$+LF$+RV$+RED$+"   "+RO$
  134. 10170 A$(2)=RV$+GRN$+"   "+RO$+DW$+LF$+RV$+GRN$+" "+RO$+BLK$+PE$
  135. 10175 A$(2)=A$(2)+RV$+GRN$+" "+RO$+DW$+LF$+RV$+GRN$+"   "+RO$
  136. 10180 A$(3)=RV$+YEL$+"   "+RO$+DW$+LF$+RV$+YEL$+"   "+RO$
  137. 10185 A$(3)=A$(3)+DW$+LF$+RV$+YEL$+"   "+RO$
  138. 10190 A$(4)=RV$+YEL$+"   "+RO$+DW$+LF$+RV$+YEL$+" "+RO$+BLK$+PE$
  139. 10195 A$(4)=A$(4)+RV$+YEL$+" "+RO$+DW$+LF$+RV$+YEL$+"   "+RO$
  140. 10200 A$(5)=RV$+YEL$+"   "+RO$+DW$+LF$+RV$+YEL$+" "+RO$+WH$+PE$
  141. 10205 A$(5)=A$(5)+RV$+YEL$+" "+RO$+DW$+LF$+RV$+YEL$+"   "+RO$
  142. 10210 A$(6)=RV$+RED$+"   "+RO$+DW$+LF$+RV$+RED$+"   "+RO$
  143. 10215 A$(6)=A$(6)+DW$+LF$+RV$+RED$+"   "+RO$
  144. 10220 A$(7)=RV$+GRN$+"   "+RO$+DW$+LF$+RV$+GRN$+"   "+RO$
  145. 10225 A$(7)=A$(7)+DW$+LF$+RV$+GRN$+"   "+RO$
  146. 10230 A$(8)=RV$+RED$+"   "+RO$+DW$+LF$+RV$+RED$+" "+RO$+BLK$+PE$
  147. 10235 A$(8)=A$(8)+RV$+RED$+" "+RO$+DW$+LF$+RV$+RED$+"   "+RO$
  148. 10240 A$(9)=RV$+GRN$+"   "+RO$+DW$+LF$+RV$+GRN$+" "+RO$+WH$+PE$
  149. 10245 A$(9)=A$(9)+RV$+GRN$+" "+RO$+DW$+LF$+RV$+GRN$+"   "+RO$
  150. 10400 CR$=RV$+YEL$+" "+RO$
  151. 10410 HDG$=RV$+WH$+"THE 'E' PUZZLE"+RO$
  152. 10420 H2$=LC$+RV$+B2$+"[212]HE '[197]' [208]UZZLE"+RO$
  153. 10430 F3$=RV$+CYN$+"FROM ?"+RO$:T3$=RV$+CYN$+"TO ?"+RO$
  154. 10440 MV$=RV$+YEL$+"MOVE #"+RO$
  155. 10445 REM- ERROR MESSAGES
  156. 10450 ER$(0)="                            "
  157. 10460 ER$(1)=RV$+YEL$+"'FROM' POSITION EMPTY"+RO$
  158. 10470 ER$(2)=RV$+YEL$+"'TO' POSITION OCCUPIED"+RO$
  159. 10480 ER$(3)=RV$+YEL$+"INVALID 'FROM-TO' POSITION"+RO$
  160. 10490 REM- END PUZZLE MESSAGE
  161. 10495 EN$=RV$+WH$+"THANKS FOR PLAYING.  'BYE."+RO$
  162. 10500 REM- PUZZLE SOLVED !
  163. 10505 WIN$=RV$+WH$+"YOU SOLVED THE PUZZLE !"+RO$
  164. 10510 REM- SOUND PARAMETERS
  165. 10515 VO=54296:WV=54276:AT=54277:HI=54273:LO=54272:F2$=""
  166. 10600 RETURN
  167. 10999 REM- PUZZLE FORMAT
  168. 11000 D$="111133332222"
  169. 11009 REM- PUZZLE SOLVED FORMAT
  170. 11010 D1$="888833339999":RETURN
  171.